Start Maple from Start Menu/Program Files/ or using the icon
in f:\math 1204

Remember to load the linear algebra package again, this time you can use
> with(LinearAlgebra):
A colon at the end instead of a semi-colon suppresses the output of all the names.

To hopefully stop you getting the same matrix as everyone else, use this command:
> Seed:=randomize():

Now create a random matrix
> F:=RandomMatrix(4,4,generator=rand(1..3));

Use 
> Rank(F);
and if it is 4, go up and press enter on the definition of F until you get one with
rank less than 4.
 alternatively, to save your time you can use a mini computer program:
F:=IdentityMatrix(4):while Rank(F)=4 do F:=RandomMatrix(4,4,generator=rand(1..3)); od:F;

Pivot F until you have it in an equivalent of RREF and check your answer and the rank using
> ReducedRowEchelonForm(F);

Notice that F will not have an inverse:
> MatrixInverse(F);
gives "singular matrix" which means there is no inverse for F

We can define 
> A:=Matrix([[2, 1, -3, -1], [1, 0, -4, 3], [0, -3, -3, -1]]);

Let the following vector be the right side of the dotted line.
> b:=Vector([8, 16, -6]);

We can also ask Maple to solve the system of equations directly:
> q1:=LinearSolve(A,b,method='none',free=s);
Notice that without the "free" Maple will uses a complicated _t notation instead of 
our s. The index of s depends on which row is used by Maple, usually s[3] for this one.

Check that v=q1 is indeed a solution for Av = b using:
> Multiply(A,q1);
(to Multiply matrices we use that command not * which is for numbers)

See what numbers you get with
> Multiply(A,F);
and note that the answer has 3 rows and 4 columns as expected

Note the error when you try to multiply them in the other order:
> Multiply(F,A);


Calculate the RREF of the system of equations:
> ReducedRowEchelonForm(<A | b>);
Notice the ratios from q1 appearing in the same way as they did in lab 1.

Extract the particular and homogeneous solutions using these commands and check 
that they multiply with A correctly:
> qp:=subs(s[3]=0,q1);
> qh:=subs(s[3]=1,q1-qp);

Find the value of s[3] which will give you a particular solution <3,2,-1,3>, using
> subs(s[3]= fill in your choice here ,q1);
What are the other values of the solution when the first entry is 0?



Define
>    G:=RandomMatrix(2,2,generator=rand(-7..7));
>    H:=RandomMatrix(2,2,generator=rand(1..5));
and check that when you multiply G and H you will probably get a different 
answer depending on which order you multiply them in.

Use Maple's inverse function to create the inverse of G
>   Gi:=MatrixInverse(G);
and check that it has the form explained in class, and the property that
when multiplied by G on either side the 2x2 matrix identity arises.

Check that Gi and
>    Hi:=MatrixInverse(H);
multiply to give the same as
>    MatrixInverse(Multiply(H,G));
only in this order and not the opposite order.


Create a random 3x3 matrix J 
> J:=RandomMatrix(3,3,generator=-4..5);
ensure that Rank(J) is 3, if not create a new random matrix until it is.

Using
> I3:=IdentityMatrix(3);
form the augmented matrix
> J1:=< J | I3 >;
and use row operations to transfom the J on the left side into I3, trying 
to keep your matrix as integers as long as possible.

Maple can calculate the inverse of any matrix too, of course:
> Jm:=MatrixInverse(J);

Note that the Determinant is the common denominator of the terms in the inverse
> Determinant(J);

Create a random 4x4 matrix K with rank 4 and pivot and use row operations with 
> K1:=<K | IdentityMatrix(4)>;
to create the inverse and check that you get the same as Maple:
> MatrixInverse(K);